neurons.f90

! Modul: Datentyp "neuron" und seine Methoden
!
! Ein Neuron implementiert eine Linearform mit Parameter-Vektor b und Offset a
! gefolgt von einer nichtlinearen Abbildung (tanh)

module neurons
  use kinds, only: wp

  implicit none
  private

  public :: neuron

  type :: neuron
     private
     real(wp) :: a
     real(wp), dimension(:), allocatable :: b
   contains
     procedure :: write
     procedure :: init
     procedure :: apply
  end type neuron

contains

  ! Ausgabe in übersichtlicher Form nach I/O-Unit u
  subroutine write (n, u)
    class(neuron), intent(in) :: n
    integer, intent(in) :: u

    write (u, "(1X,A)")  "Neuron:"
    write (u, "(3x,A,1x,F11.9)")  "a    =", n%a
    if (allocated (n%b)) then
       write (u, "(3x,A,*(1x,F11.9))")  "b    =", n%b
    else
       write (u, "(3x,A,1x,A)")      "b    =", "[leer]"
    end if

  end subroutine write
  
  ! Initialisierung mit Werten für a und b
  subroutine init (n, a, b)
    class(neuron), intent(out) :: n
    real(wp), intent(in) :: a
    real(wp), dimension(:), intent(in) :: b

    n%a = a
    n%b = b

  end subroutine init
  
  ! Anwendung der Abbildung auf Vektor x
  function apply (n, x) result (z)
    class(neuron), intent(in) :: n
    real(wp), dimension(:), intent(in) :: x
    real(wp) :: z

    real(wp) :: y

    y = n%a + dot_product (n%b, x)
    z = tanh (y)

  end function apply

end module neurons